イラスト、モデリング、Unity、VR関連

unityとかblenderとかvr関連の作業メモ

shader レイマーチ、　三角繰り返し

 

Shader "Custom/Ray21"{
	Properties{
		_R("R",Float) = 1
		_Scale("Scale",Int) = 5
		_SplitNum("SplitNum",Range(0,100)) = 30
		_Origin("Origin",Vector) = (0,0,0,0)
		_TRNum("TRNum",Int) = 100
	}
	SubShader{
		Tags { "RenderType" = "Opaque" "LightMode" = "ForwardBase" }
		LOD 100
		Cull Back
		Pass{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "UnityCG.cginc"

			float _R;
			float _Scale;
			float4 _Origin;
			int _SplitNum;
			int _TRNum;
			struct appdata{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f{
				float2 uv : TEXCOORD0;
				float3 lpos : TEXCOORD1;
				float4 vertex : SV_POSITION;
			};

			v2f vert(appdata v){
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.lpos =v.vertex.xyz;//メッシュのローカル座標を代入
				o.uv = v.uv;
				return o;
			}

			float Triangle(float3 z)
			{
				float3 a1 = float3(1,1,1);
				float3 a2 = float3(-1,-1,1);
				float3 a3 = float3(1,-1,-1);
				float3 a4 = float3(-1,1,-1);
				float3 c;
				int n = 0;
				float dist, d;
				float scale = 2;
				while (n < 15) {
					 c = a1; dist = length(z-a1);
				   d = length(z-a2); if (d < dist) { c = a2; dist=d; }
					 d = length(z-a3); if (d < dist) { c = a3; dist=d; }
					 d = length(z-a4); if (d < dist) { c = a4; dist=d; }
					z = scale*z-c*(scale-1.0);
					n++;
				}

				return length(z) * pow(scale, float(-n));
			}

			float sphere(float3 p){
				return length(p) - _R;
			}

			float3 mod(float3 a, float3 b){
		 		return frac(abs(a / b)) * abs(b);
			}

			float3 trans(float3 p){
    		return mod(p, _Scale) - _Scale/2.0;
			}

			float dist(float3 p){
				//return length(trans(p-_Origin)) - _R;
				return Triangle(p);
			}

			float3 getnormal(float3 p){
				float d = 0.0001;
				return normalize(float3(
					dist(p + float3(d, 0.0, 0.0)) - dist(p + float3(-d, 0.0, 0.0)),
					dist(p + float3(0.0, d, 0.0)) - dist(p + float3(0.0, -d, 0.0)),
					dist(p + float3(0.0, 0.0, d)) - dist(p + float3(0.0, 0.0, -d))
				));
			}


			fixed4 frag(v2f i) : SV_Target{
				float3 start = mul(unity_WorldToObject,float4(_WorldSpaceCameraPos,1)).xyz;//レイのスタート位置をカメラのローカル座標とする
				//メッシュのローカル座標の、視点のローカル座標からの方向を求めることでレイの方向を定義
				float3 onelay = normalize(i.lpos.xyz - mul(unity_WorldToObject,float4(_WorldSpaceCameraPos,1)).xyz);

				float d =0;
				float t=0.001;
				for (int i = 0; i < _SplitNum; ++i) { //レイマーチのループを実行
					d = dist(start + onelay * t);
						t += d;
						//レイがどこにもぶつからずはるか遠くに行くか、ほぼ衝突していて進む距離がほとんどなくなったらループを終了する
						if (d < 0.01 || t > 1000) {
							break;
						}
				}
				float4 col = 1;
				if (d > 0.01||t>1000) { //レイが遠くに行っているか、衝突していないと判断すれば描画しない
					clip(-1);
				}
				else {
					float3 normal = getnormal(start+onelay * t);
					float3 lightdir = normalize(mul(unity_WorldToObject, _WorldSpaceLightPos0).xyz);//オブジェクトスペースで計算しているので、ディレクショナルライトの角度もオブジェクトスペースにする
					float NdotL = max(0, dot(normal, lightdir));
					col = float4(float3(1,1,1)*NdotL,1);//ランバート反射を計算
				}
				return col;
			}
			ENDCG
		}//pass
	}//subshader
}